warpeffekt mit text?

[gelaniee]

Hallo Zusammen,

ich habe hier im forum einen Link gefunden zu flashstar's "warpeffekt".
Diesen finde ich ziemlich toll und würde ihn gerne verwenden, nur statt der sterne etwas Text verwenden. Die Sterne werden hier jedoch mit Actionscript erstellt und da ich leider nicht viel Ahnung habe, weiß ich nicht so recht, was ich in dem Script ändern muß. Es wäre toll wenn mir das jemand zeigen könnte. Danke im voraus, hier das Script:

MovieClip.prototype.genStern = function(tempo) {
	this.x = random(Stage.width)-Stage.width/2;
	this.y = random(Stage.height)-Stage.height/2;
	this.z = 1000;
	this.onEnterFrame = function() {
		if ((this.z -= tempo)<-100) {
			this.removeMovieClip();
		} else {
			this.zeichneStern(1,150,20);
		}
	};
};
MovieClip.prototype.zeichneStern = function(dicke, referenz, laenge) {
	this.clear();
	this.lineStyle(dicke-this.z/200, 0xffffff, 100);
	perspektive = referenz/(referenz+this.z);
	this.moveTo(this.x*perspektive, this.y*perspektive);
	perspektive = referenz/(referenz+this.z+laenge);
	this.lineTo(this.x*perspektive, this.y*perspektive);
};
this.createEmptyMovieClip("universum",1);
var tiefe = 1;
universum._x = Stage.width/2;
universum._y = Stage.height/2;
universum.onEnterFrame = function() {
	this.createEmptyMovieClip("stern"+tiefe, tiefe++).genStern(10);	
};

Grüßle, Gelaniee

 

[Tobias Menzel]

Hi,

bitte poste die komplette Datei, denn der nackte Code ist nicht lauffähig.

Gruß
.

 

[gelaniee]

Oh, entschuldigung, hier ist die .fla-Datei.

 

[Tobias Menzel]

Danke.

Wie hast Du Dir das Ergebnis (mit Text) denn vorgestellt? 1:1 übernehmen wirst Du die Vorlage nicht können, da die Sterne hier in der Tat in Form von Linien gezeichnet werden. Du willst anscheinend MovieClips (oder Textfelder) animieren - soll nur die Position geändert werden, oder sollen die Dinger auch irgendwie verzerrt werden?

Gruß
.

 

[gelaniee]

Sowas hab ich schon befürchtet.

Es sollte eigentlich nur ein kleiner Text: ROCK THE KITCHEN sein, welcher auch immer gleich bleibt, nur eben die Größe verändert, damit's dreidimensional wirkt. Und, schön wäre vielleicht auch wenn die Schrift die noch weiter weg, also kleiner ist auch etwas unscharf wäre (blur?)...aber davon wage ich bei meinen mangelnden Kenntnissen kaum zu träumen:suspekt:

Vielleicht gibt es irgendwo ein Tutorial dazu?

Grüßle, Gelaniee

 

[Tobias Menzel]

in etwa so (siehe Anhang)?

Gruß
.

 

[gelaniee]

...ohhh, ich kann die Datei nicht öffnen, weil sie "Bildschirme" enthält. Ich habe nur Flash 8 Basic, damit geht das nicht.
Aber, es wär bestimmt ziemlich toll und ich weiß nicht, ob ich etwas zu altmodisch bin, aber, ich würd mich gern mal irgendwie bei Dir bedanken. Du hast mir schon so oft aus der Klemme geholfen. Da ich in Flash nicht so gut bin könnt ich Dir vielleicht mal ein paar Foodfotos senden?...& die Rezepte dazu...hab leider keine andere Idee mich mal erkenntlich zu zeigen.

Grüßle, Gelaniee

 

[Tobias Menzel]

hmm ... ich habe die Datei stinknormal mit Flash 9 für Flash 8 (ohne "Bildschirme o.ä.) gespeichert.

Hier noch einmal das ganze mit Flash 8 selbst gespeichert (Anhang).

Falls es immer noch nicht klappt: In der Bibliothek befindet sich ein MC mit dem Verknüpfungsbezeichner "logo". Er enthält Deinen Schriftzug (mittig am Nullpunkt zentriert). Auf Frame 1 der Hauptzeitleiste befindet sich folgendes Script:

import flash.filters.BlurFilter;

var cx = Stage.width / 2;

var cy = Stage.height / 2;

var max = 2000;

var iv = setInterval(this, "addLogo", 300);

function addLogo() {
	var d = this.getNextHighestDepth();
	var logo = this.attachMovie("logo", "logo" + d, d);
	logo.ang = Math.random() * Math.PI * 2;
	logo.dist = 0.1;
	logo._xscale = logo._yscale = logo.dist;
	logo.spd = 1.006;
	logo.onEnterFrame = function() {
		this.dist *= this.spd;
		this.spd += 0.0015;
		if (this.dist >= max) this.removeMovieClip();
		this._alpha = 200 - (this.dist / (max / 200));
		this._xscale = this._yscale = this.dist;
		var w = (max - this.dist) / (max / 4);
		if (w < 0) w = 0;
		var f = new BlurFilter(w, w, 2);
		this.filters = new Array(f);
		this._x = cx - Math.sin(this.ang) * this.dist / 4;
		this._y = cy + Math.cos(this.ang) * this.dist / 4;
	}
}

Mit den Variablenwerten kannst Du ein wenig experimentieren.

Gruß
.

 

[gelaniee]

Hallo Tobias,

irgendwie klappt das nicht mit dem öffnen Deiner Datei, aber ich habs so gebaut wie Du geschrieben hast und es ist super. Genau so hab ich mir das vorgestellt. Jetzt muß ich leider fort, aber heut Nacht spiele ich noch etwas damit herum und dann poste ich nochmal das Ergebnis.

Vielen Dank, Gelaniee