✔ Direkte Hex umwandlung

[Dentol]

Hallo,

ich will Prog erstellen womit ich Dateien von einem Spiel editieren will. Diese sind aber verschlüsselt und das Prog soll dies sofort entschlüsseln und in einer Textbox ausgeben. (und speichern wäre auch toll)

Die Spieltdateien entschlüsselt man mit einem Hexeditor (in dem Fall Hexworkshop)so:

Tools>Operations > XOR
Treat data As > 8 Bit Unsigned Byte
Value : EF (Hex)
entire file und ok

Wie kann ich das meinem Programm beibringen? (Ich benutze VB 6.0)

 

[DrSoong]

Also, die Verschlüsselung ist eine XOR-Verschlüsselung? Könnte dann so aussehen:

'Form mit CommandButton (Command1) und 2 Textboxen (Text1, Text2)
Private Sub Command1_Click()
 Dim sDateiname As String, sInhalt As String, sEntschlüsselt As String, sByte As String
 Dim iFile As Integer, iKey As Integer, cnt

 'Schlüssel festlegen
 iKey = 239 'Hex EF
 'In Text1 sollte sich der Name der Datei befinden (inklusive Pfad)
 sDateiname = Text1.Text
 'Eingangsvariable vorbelegen
 sInhalt = Space(FileLen(sDateiname))
 'Freie Dateinummer holen
 iFile = FreeFile

 'Datei binär öffnen
 Open sDateiname For Binary As iFile
  'ganze Datei einlesen
  Get #iFile, , sInhalt
 Close iFile

 'Eingelesenen Code in einer Schleife prüfen
 For cnt = 1 To Len(sInhalt)
  'Zeichen für Zeichen auslesen
  sByte = Mid(sInhalt, cnt, 1)
  'und dekodieren
  sByte = Chr(Asc(sByte) Xor iKey)
  'und in neue Variable speichern
  sEntschlüsselt = sEntschlüsselt & sByte
 Next cnt

 'Entschlüsselten Text in Textbox schreiben
 Text2.Text = sEntschlüsselt

 'und auch in neue Datei speichern (Endung .enc)
 sDateiname = sDateiname & ".enc"
 iFile = FreeFile
 Open sDateiname For Binary As iFile
  Put #iFile, , sEntschlüsselt
 Close iFile
End Sub

Ungetestet, da hier kein VB, sollte aber funktionieren.


Der Doc!

 

[Dentol]

OK danke, klappt wunderbar