✔ Directory und Drivelist in einem - geht das auch?

[MacInternet]

Hallo, ich schlage mich hier schon wieder mit einem Problem herum, für das ich noch keine befriedigende Lösung gefunden habe:

Ich möchte dem Anwender die Möglichkeit geben, bestimmte Pfade im Programm einzustellen. Aber das, was VB 6.0 bietet, ist doch ein bisschen veraltet:

Drives und Directories werden dort grundsätzlich getrennt eingegeben. Das ist sehr unübersichtlich für Anwender, finde ich.

Gibt es eine Möglichkeit, ein einziges Auswahlfenster für die Pfadauswahl anzuzeigen, in welchem neben den Ordnern auch die verschiedenen Laufwerke berücksichtigt werden?
Vielleicht mit irgendwelchen Komponenten oder so, die eingebunden werden können?
Kennt sich jemand damit aus?

Viele Grüsse und vielen Dank schon mal im voraus,
Mac

 

[ronaldh]

Hallo,

pack Dir folgenden Code in ein Modul:

Option Explicit

Private Const BIF_RETURNONLYFSDIRS = 1
Private Const BIF_DONTGOBELOWDOMAIN = 2
Private Const MAX_PATH = 260

Private Declare Function SHBrowseForFolder Lib "shell32" _
                                  (lpbi As BrowseInfo) As Long

Private Declare Function SHGetPathFromIDList Lib "shell32" _
                                  (ByVal pidList As Long, _
                                  ByVal lpBuffer As String) As Long

Private Declare Function lstrcat Lib "kernel32" Alias "lstrcatA" _
                                  (ByVal lpString1 As String, ByVal _
                                  lpString2 As String) As Long

Private Type BrowseInfo
   hWndOwner      As Long
   pIDLRoot       As Long
   pszDisplayName As Long
   lpszTitle      As Long
   ulFlags        As Long
   lpfnCallback   As Long
   lParam         As Long
   iImage         As Long
End Type

Public Function SelectFolder(frm As Form, Optional cTitle = "") As String
'Opens a Treeview control that displays the directories in a computer

   Dim lpIDList As Long
   Dim sBuffer As String
   Dim szTitle As String
   Dim tBrowseInfo As BrowseInfo

   szTitle = cTitle
   With tBrowseInfo
      .hWndOwner = frm.hwnd
      .lpszTitle = lstrcat(szTitle, "")
      .ulFlags = BIF_RETURNONLYFSDIRS  ' + BIF_DONTGOBELOWDOMAIN
   End With

   lpIDList = SHBrowseForFolder(tBrowseInfo)

   If (lpIDList) Then
      sBuffer = Space(MAX_PATH)
      SHGetPathFromIDList lpIDList, sBuffer
      sBuffer = Left(sBuffer, InStr(sBuffer, vbNullChar) - 1)
      SelectFolder = sBuffer
   End If
End Function

...und ruf die Funktion auf mit:

    Dim Verzeichnis as String
     Verzeichnis = SelectFolder(Form1, "Suche Verzeichnis")

Ich hoffe, Dir damit geholfen zu haben.

Viele Grüsse
ronaldh

 

[MacInternet]

Boah, klasse - das ist ja genau das, was ich gesucht habe
Vielen herzlichen Dank *freu*

Mac