Daten via Link versenden

Hi

Du kannst natürlich einen Datensatz über den QueryString() versenden. Es kommt auf den Datensatz an. Du kannst auch ein Forumlar über einen Link absenden.

Es gibt aber bestimmt auch andere Lösungen.
Einfach mal näher beschreiben was Du vor hast.
 
Nehmen wir gleich meinen bestehenden Code:

Code: 
<%@ Language=VBScript %>
<%
dim vname ' ---
dim vfirstname ' ---
dim vplz ' ---
dim counter ' ---
counter = 1
dim intpagecounter
intpagecounter = 1
'dim counter1 ' ---
'dim c ' ---
dim pagesize ' --- Definieren der Seitengröße (Anzahl Datensätze pro Seite)
pagesize = 5
dim actpage
actpage = Request("PN")
vname = Request("fname")
if vname <> "" Then 
    strCond = "and  name = " & chr(34) & vname & chr(34) 
End if
vfirstname = Request("ffirstname")
if vfirstname <> "" Then 
    strCond = strCond & " and  firstname = " & chr(34) & vfirstname & chr(34) 
End if
vplz = Request("fplz")
if vplz <> "" Then 
    strCond = strCond & " and  plz = " & chr(34) & vplz & chr(34) 
End if
set ors = CreateObject("ADODB.RECORDSET") 'ors = objetrecordset
set Ocn = CreateObject("ADODB.Connection") 'ocn = objectconnect
ors.PageSize = pagesize
ors.CacheSize = pagesize
ocn.open "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=D:\adb.mdb;"'Verbindung zur Datenbank wird erstellt
ors.Open "Select * from adressbook where 1=1 " & strCond & " order by ID ",ocn,3,3
if actpage = "" or not isnumeric(actpage) or cint(actpage) > cint(ors.PageCount) then
actpage = 1
end if
dim datarec
datarec = ors.RecordCount
dim maxpage
maxpage = fix(datarec/pagesize)
if (maxpage*pagesize) < datarec then maxpage = maxpage + 1
if counter > maxpage then counter = maxpage 
%>
<%
sub arrowleft
if cint(actpage) <= 1 then
 response.Write Server.HTMLEncode("<<")
else
 Response.Write "<a href=""list.asp?PN=" & actpage - 1 & """>" & Server.HTMLEncode("<<") & "</a>"
end if
end sub
sub arrowright
if cint(actpage) < cint(maxpage) then
    Response.Write "<a href=""list.asp?PN=" & actpage + 1 & """>" & Server.HTMLEncode(">>") & "</a>"
else
    response.Write Server.HTMLEncode(">>")
end if
end sub
sub sitenumber
for intpagecounter = 1 to ors.PageCount
if cint(intpagecounter) = cint(actpage) then
 Response.Write intpagecounter & ""
else
 Response.Write "<a href=""list.asp?PN=" & intpagecounter & """> " & intpagecounter & " </a>"
end if
next
end sub
%>
<%
        if not ors.EOF then
        ors.AbsolutePage = actpage
        end if
        %>
<HTML>
<HEAD>
<META NAME="GENERATOR" Content="Microsoft Visual Studio 6.0">
</HEAD>
<BODY>
<table border=1 align=center>
<tr>
<th bgcolor="#b9b9b9" colspan="12">Adressliste; Seite <%=actpage%>; Anzahl Datensätze: <%=datarec%>; <%=maxpage%></th>
</tr>
<tr>
    <td>ID</td>
    <td>Vorname</td>
    <td>Name</td>
    <td>Strasse</td>
    <td>Nummer</td>
    <td>PLZ</td>
    <td>Ort</td>
    <td>Telefon</td>
    <td>Fax</td>
    <td>E-Mail</td>
    <td>Editieren</td>
    <td>Löschen</td>
</tr>
<%
if ors.RecordCount > 0 then
    do while not ors.EOF and counter <= pagesize%>
        
        <tr>
            <td>
            <%=ors("id")%>
            </td>
            <td>
            <%=ors("firstname")%>
            </td>
            <td>
            <%=ors("name")%>
            </td>
            <td>
            <%=ors("street")%>
            </td>
            <td>
            <%=ors("number")%>
            </td>
            <td>
            <%=ors("plz")%>
            </td>
            <td>
            <%=ors("location")%>
            </td>
            <td>
            <%=ors("phone")%>
            </td>
            <td>
            <%=ors("fax")%>
            </td>
            <td>
            <%=ors("e-mail")%>
            </td>
            <td>
            <%response.Write "<a href=""edit.asp"">"%>Editieren<%response.Write "</a>"%>
            </td>
            <td>
            <%response.Write "<a href=""delete.asp"">"%>Löschen<%response.Write "</a>"%>
            </td>
        </tr>
        <%counter = counter + 1
        ors.MoveNext
    loop
else
    response.Redirect "default.asp"
end if
%>
</table>
<table align=center>
<tr>
<td>
<%
'response.Write "<a href=""list.asp"">" & Server.HTMLEncode("<<") & "</a>"
arrowleft
%>
</td>
<td>
<%
sitenumber
%>
</td>
<td>
<%
'response.Write "<a href=""list.asp"">" & Server.HTMLEncode(">>") & "</a>"
arrowright
%>
</td>
</tr>
</table>
<br>
<br>
<center><a href="default.asp">Start</a></center>
 
<%ors.Close
set ors = nothing
ocn.Close
set ocn = nothing
%>
</BODY>
</HTML>

Wie man sieht, habe ich in der Tabelle die ausgegeben wird, zwei Links: Editieren und Löschen...

Wenn ich nun zum Beispiel hinter der Zeile mit der ID 1 löschen klicke, sollte sich die Seite delete.asp öffnen und mich fragen ob ich den Datensatz wirklich löschen will. Natürlich muss ich generell erst einmal dem jeweiligen Link, die ID zuweisen...
 
Achso, Du willst keinen ganzen Datensatz übergeben sondern nur die ID?

Code: 
<a href="delete.asp?id=<%=ors("ID")%>" onClick="return confirm('Wirklich Löschen?')">Datensatz löschen</a>

Übrigens für das Löschen eines Datensatzes da braucht man keine extra Seite. Das kann man auch über eine Prozedur machen. Wird der Link angeklickt, wird die Prozedur oder Funktion aufgerufen und abgearbeitet.
 
Zuletzt bearbeitet:
Danke, das hat soweit geklappt...

Aber nun schnell ne Frage zu confirm()... ist dies nicht eine javascript-Funktion?
 
ja stimmt.
Würde ich beim Löschen über einen Link immer anfordern. Denn wenn es erstmal gelöscht ist, ist es weg, zumindest wenn kein weiterer Zwischenschritt existiert.
 
das ist doch nur eine clientseitige Javascript-Funktion.
Hat doch mit den serverseitigen vbScript-Funktionen nix zu tun. ;)
 
Ich übe und übe und übe und, etc. aber ich kriege diesen Code:
Code: 
onClick="return confirm('Wirklich Löschen?')"
nicht hier rein:
Code: 
<td>
<%Response.Write "<a href=""delete.asp?ident=" & ors("id") & """>"%>Löschen<%response.Write "</a>"%>
</td>

Wenn ich was umstelle baut sich auf einmal die Seite gaze seltsam auf... hab dann auf einmal 4 Editieren-Links und so...

Könntest du mir helfen Luzie? Und warum braucht es nach & ors("id") & noch zwei "?
 
Warum machst Du es Dir so kompliziert?

Du hast doch nur ors("id") als ASP-Script einzufügen, der Rest ist html.
Schau Dir doch nochmal mein Posting #4 an.

return confirm() muss allerdings in einer Zeile stehen.

Code: 
<a href="delete.asp?id=<%=ors("ID")%>" onClick="return confirm('Wirklich Löschen?')">Datensatz löschen</a>
 
Zuletzt bearbeitet:
Um antworten zu können musst du eingeloggt sein.

Neue Beiträge

Zurück