bistimmte zeilen in txt files

[Waescher]

Hi Solidus!

kuck, das ganze ist wirklich mehr als einfach:

1. Anlegen eines ini-Modules:

Füge deinem Programm ein neues Modul zu, und kopier folgenden Code rein:

  Option Explicit
    
    '//--------------------------------------------------------------------------
    '// INI Funktionen
    '//--------------------------------------------------------------------------
    
    Private Declare Function GetPrivateProfileString Lib "Kernel32" Alias _
       "GetPrivateProfileStringA" (ByVal lpApplicationName As String, _
        ByVal lpKeyName As Any, ByVal lpDefault As String, _
        ByVal lpReturnedString As String, ByVal nSize As Long, _
        ByVal lpFileName As String) As Long
    
    Private Declare Function WritePrivateProfileString Lib "Kernel32" Alias _
       "WritePrivateProfileStringA" (ByVal lpApplicationName As String, _
       ByVal lpKeyName As Any, ByVal lpString As Any, _
       ByVal lpFileName As String) As Long
    
    Public INIFILEPATHNAME As String
    
    Public Sub SetIniString(ByVal sSection As String, ByVal sKey As String, _
                                    ByVal sValue As String)
         If INIFILEPATHNAME = "" Then Exit Sub
         WritePrivateProfileString sSection, sKey, sValue, INIFILEPATHNAME
    End Sub
    
    Public Function GetIniString(ByVal sSection As String, _
                                                ByVal sKey As String) As String
        Dim nResult As Long
        Dim sBuffer As String
    
        If INIFILEPATHNAME = "" Then Exit Function
        sBuffer = Space(255) ' max. Stringlänge 255 Bytes
        nResult = GetPrivateProfileString(sSection, sKey, "", sBuffer, 255, _
                                INIFILEPATHNAME)
    
        If nResult Then
            GetIniString = Left(sBuffer, nResult)
        End If
    End Function

2. Aufrufen der Ini-Funktionen

Dabei ist es völlig egal, was für eine File du hast (*.cfg, *.ini, *.txt ...)

Ini initialisieren:
INIFILEPATHNAME = "C:\MeinTollerEditor\Settings.cfg"

Schreiben:
Call SetIniString("Überschrift", "Key", "Wert")

So sieht dann deine Ini aus:

    [Überschrift]
    Key=Wert

Auslesen kannst du das ganze so:
GetIniString("Überschrift","Key")
Was dann der String "Wert" wär.

Einfach oder?

Hoffe dir geholfen zu haben...

mfG Wäscher