[Asp] Problem SMTPsvg Mailer

Chris B

Mitglied
Guten morgen

Der Mailer unsere Forums geht aus irgendwelchen Gründen nich und ich muss das irgendwie beheben :)

Ich bin jetzt endlich soweit bekommen und hab die Datei mit dem Mailer gefunden, ein wenig getestet und dann mal einen Mailer auf einem Tutorial verwendet.

Code:
Set Mailer = Server.CreateObject("SMTPsvg.Mailer")
	Mailer.CharSet = 2
	Mailer.ContentType = "text/html"
	Mailer.Organization = "xxx"
	Mailer.FromName = "BlaBla"
	Mailer.FromAddress = "info@xx.de"
	Mailer.RemoteHost = "mail.xxx.de"
	Mailer.ClearAllRecipients
	Mailer.AddRecipient "Chris Biehl", "christian.biehl@xxx.de"
	Mailer.Subject = "Betreff:Der Betreff"
	Mailer.ClearBodyText
	Mailer.BodyText = "Text der Mail"
	If Mailer.SendMail Then
		SendMail = True
		m_errortext = "Die eMail wurde erfolgreich versendet."
		Else
			SendMail = False
			m_errortext = Mailer.Response
			Response.Write(m_errortext &"<br>")
	End if
	
Response.Write(mailer.CharSet & "<br>")
Response.Write(mailer.Organization & "<br>")
Response.Write(mailer.FromName & "<br>")
Response.Write(mailer.FromAddress & "<br>")
Response.Write(mailer.RemoteHost & "<br>")
Response.Write(mailer.Subject  & "<br>")
Response.Write(mailer.BodyText & "<br>")

Set Mailer = Nothing

Die Responses am Schluss haben folgendes gezeigt:

This evaluation component has expired.
2
xxx
BlaBla
info@xx.de
mail.xxx.de
Betreff:Der Betreff

Microsoft VBScript runtime - Fehler '800a01b6'
Object doesn't support this property or method: 'BodyText'
/forum/inc_mail.asp, line 102

102 = Response.Write(mailer.BodyText & "<br>")
Weiss jemand vielleicht warum er die BodyText Methode nicht kennt?

Lg Chris
 
Zuletzt bearbeitet:

Isac

Erfahrenes Mitglied
Code:
dim mes, sTo, SFrom, sSubject, sMailServer, sBody, objMail, objConf, objFields
	mes = ""
IsSuccess = false
sTo =  empfaengermail
sFrom = sendermail
sSubject = subject
sMailServer = IP-Adresse
sBody= strTextBody & strHTMLBody 
  
Set objMail = Server.CreateObject("CDO.Message")
	Set objConf = Server.CreateObject("CDO.Configuration") 
	Set objFields = objConf.Fields
	
	With objFields
		.Item("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2
		.Item("http://schemas.microsoft.com/cdo/configuration/smtpserver")  = sMailServer 
		.Item("http://schemas.microsoft.com/cdo/configuration/smtpconnectiontimeout") = 10 
		.Item("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 25
		.Update 
	End With

	With objMail
		Set .Configuration = objConf
		.From = sFrom
		.To = sTo
		.Subject = sSubject
		.HTMLBody = sBody
	End With
    
    Err.Clear 
	'on error resume next

    objMail.Send
	if len(Err.Description) = 0 then
         MailOK = true
    else
		 MailOK = false
    MailResponse = objMail.Response
	end if
   
	Set objFields = Nothing
	Set objConf = Nothing
	Set objMail = Nothing

hier noch der Code von meinem Script. Müsste wohl noch ein bisschen angepasst werden aber das schafftst du schon :)

P.S. Es wird ein HTMLBody benutzt. Kannst somit auch Bilder u.ä. mitschicken
 
Zuletzt bearbeitet: