Zinserechen-Programm in VBA

[Manuel Rosenmueller]

hallo zusammen,

ich muss so n programm schreiben das mir ausrechnet wielange ich brauch um ein bestimmtes kapital bei einem bestimmtem zinsatz zu erreichen - ich hab jetzt schon soviel ausprobiert aber ichkomm ned drauf - kennt sich jemand damit aus und mag mir helfen ?

danke!

gruss manuel!

 

[Thomas Darimont]

Hallo!

Option Explicit

Private Sub CommandButton1_Click()

Dim endKapital As Double
Dim anfangsKap As Double
Dim zinsSatz As Double

Dim n As Double 'Jahre

anfangsKap = InputBox("Anfangskapital eingeben")
endKapital = InputBox("Endkapital eingeben")
zinsSatz = InputBox("Zinssatz eingeben")

'kn = k0 * q^n
'
'entweder mit formel
'
' n = lg(kn/k0) / lg(q)

n = Log10(endKapital / anfangsKap) / Log10(zinsSatz / 100 + 1)

MsgBox "Um mit einem Kapital von " & anfangsKap & " ein Endkaptial von " & endKapital & " bei " & zinsSatz & "% Zinsen zu erreichen brauchst man mindestens " & IIf(CInt(n) < n, CInt(n + 1), n) & " Jahre"


'oder per Schleife

n = 0

While anfangsKap < endKapital
    anfangsKap = anfangsKap * (1 + zinsSatz / 100)
    n = n + 1
Wend

MsgBox "Um mit einem Kapital von " & anfangsKap & " ein Endkaptial von " & endKapital & " bei " & zinsSatz & "% Zinsen zu erreichen brauchst man mindestens " & n & " Jahre"


End Sub

Static Function Log10(X)
    Log10 = Log(X) / Log(10#)
End Function

Gruß Tom

 

[Manuel Rosenmueller]

jep danke - so einfach kanns doch manchmal sein!

gruss manuel!