✔ VBA Datum von bis fortlaufend

[Yaslaw]

Schon mal daran gedacht, das mit einer Datenbank zu lösen?

zu deinem Problem.
Spalte L (Datum). Ist das fest eingetragen?
So wie ich das jetzt verstehe. Vorne wird Von Bis und der Type eingetragen. Wenns genemigt ist, soll die Spalte D (UrlStat) in die Spalte O (Url) eingetragen werden, bei allen Daten die im Ferienrange drin sind.

Stimmt das so?

 

[Yaslaw]

Hier mal ein Wurf. Den muss man noch veralgemeinern

Const C_VON = "A"
Const C_BIS = "B"
Const C_URLSTAT = "D"
Const C_DATE = "L"
Const C_URL = "O"

Public Sub transformHolidays()
    Dim ws As Worksheet
    Dim srcRowNr As Long, trgRowNr As Long
    Dim fromDate As Date, toDate As Date, checkDate As Date
    Dim urlStat As String
   
    Set ws = ActiveWorkbook.Worksheets("30000159")
   
    srcRowNr = 2    'Auf der 2ten Zeile mit auslesen beginnen
   
    Do While IsDate(ws.Range(C_VON & srcRowNr).Value)
        fromDate = ws.Range(C_VON & srcRowNr).Value
        toDate = ws.Range(C_BIS & srcRowNr).Value
        urlStat = ws.Range(C_URLSTAT & srcRowNr).Value
       
        trgRowNr = 2
        Do While IsDate(ws.Range(C_DATE & trgRowNr).Value)
            checkDate = ws.Range(C_DATE & trgRowNr).Value
            If checkDate >= fromDate And checkDate <= toDate Then
                ws.Range(C_URL & trgRowNr).Value = urlStat
            End If
            trgRowNr = trgRowNr + 1
        Loop
        srcRowNr = srcRowNr + 1
    Loop
   
End Sub

 

[Sharki77]

Hi,

ja hab mal darüber nachgedacht das mittels einer datenbank zu machen. leider habe ich davon noch weniger Ahnung als Excel also für meine Kenntnisse quasi Unmöglich

Beüglich deiner Erläuterung folgendes:

Spalte L beinhaltet das Statische Datum und ist Fix
Spalte A und B wird dann mittels des Formulares Beginn und Ende eingetragen. der Status in Spalte D entscheidet dann ob der Urlaub genehmigt wurde bzw. nur Urlaubsplanung ist. dieser Status sollte dann in Spalte M eingetragen werden. Leider klappt das nicht so wie ich mir das vorgestellt hatte. Ich hatte mittels "ungenauer" Suche mit dem SVERWEIS einige Erfolge, habe aber gleichermaßen auch Rückschläge erlitten, da dieser warum auch immer nur bis Zeil 27 richtig auswertete und danach nur noch fehler kommen.
Wie du siehst ist das alles ein bisschen differenzierter und komplizierter
aber ich hoffe man konnte ein leihenhaftes BLABLA verstehen...

Dein Code werde ich die Tage mal integrieren und genauer unter die Lupe nehmen was der wo macht. (P.s. dauert bei mir immer was länger )

Gruß

 

[Yaslaw]

Mehr oder weniger mein Code, was ud da beschreibst. Musst schauen ob die Spalten stimmen. Und dann noch den Worksheet-Name als Paramter nehmen damit du die 10 Tausend anderen identischen Worksheets abarbeiten kannst.