✔ Probleme mit MovieClipLoader/.swf ladt nicht!

[dreamer2007]

Hallo zusammen,

hier zunächst mal der code:

content_change = function (inhalt_id:Number):Void {
	_root.removeMovieClip("mc_contentcontainer");
	// Falls Contentcontainer schon vorhanden, dann Löschen;
	var contentcontainer:MovieClip = _root.createEmptyMovieClip("mc_contentcontainer", _root.getNextHighestDepth());
	contentcontainer._x = 30;
	contentcontainer._y = 100;
	// Contentcontainer mit erforderlichen Variablen erzeugen
	var sideani_link:String = new String("");
	var textcontainer:MovieClip = contentcontainer.attachMovie("textframe", "mc_textcontainer", contentcontainer.getNextHighestDepth());
	var sidecontainer:MovieClip = contentcontainer.createEmptyMovieClip("mc_sidecontainer", contentcontainer.getNextHighestDepth());
	// XML Daten aus contentXXXX.xml laden
	var xmlContent:XML = new XML();
	xmlContent.ignoreWhite = true;
	xmlContent.load("../xml/content"+inhalt_id+".xml");
	xmlContent.onLoad = function():Void  {
		if (xmlContent.loaded && this.firstChild.childNodes) {
			menuPunkt = this.firstChild.childNodes;
			sideani_link = (/*"sideani/"+menuPunkt[0].firstChild.nodeValue+".swf"*/"menu.swf");
			textcontainer.inhalt.htmlText = menuPunkt[1].firstChild.nodeValue;
			
			trace(sideani_link);
		}
	};
	var mcLoader:MovieClipLoader = new MovieClipLoader();
	var listener:Object = new Object();
	listener.onLoadProgress = function(target:MovieClip, bytesLoaded:Number, bytesTotal:Number):Void  {
		trace(target+".onLoadProgress with "+bytesLoaded+" bytes of "+bytesTotal);
	};
	listener.onLoadInit = function(target_mc:MovieClip) {
		trace("movie loaded");
		sidecontainer._x = 100;
		sidecontainer._y = 100;
	};
	listener.onLoadError = function(target_mc:MovieClip, errorCode:String, httpStatus:Number) {
		trace(">> loadListener.onLoadError()");
		trace(">> ==========================");
		trace(">> errorCode: "+errorCode);
		trace(">> httpStatus: "+httpStatus);
	};
	listener.onLoadStart = function(target_mc:MovieClip) {
    	trace(">>===========================\nDownload started");
	};

	mcLoader.addListener(listener);
	mcLoader.loadClip(sideani_link, contentcontainer);
};

content_change("0001");

Ich versuche innerhalb einer function eine swf-Datei über die MovieClipLoader-Klasse zu laden. Allerdings tut sich garnichts. Ich habe schon alles mögliche ausprobiert. Zunächst war meine Vermutung es liegt an einer falschen Ebenen-Tiefe aber auch durch ändern dieses Parameters tut sich nichts.

Vielleicht habt ihr ja eine Lösung oder seht auf Anhieb woran es liegen kann.

LoadClip wird anscheinend nicht mal ausgeführt, denn entsprechende traces werden nicht mal ausgegeben.


Bin für jeden Tipp dankbar...


Gruß Dreamer

 

[1manni1]

Ob der Compiler mit der Codezeile zufrieden ist bezweifle ich Aber war denke ich nur zu Testzwecken.

sideani_link = (/*"sideani/"+menuPunkt[0].firstChild.nodeValue+".swf"*/"menu.swf");

Dann machst du ein Fehler im der Logik. Du lädst die XML und da definierst du wenn diese fertig geladen ist sideani_link.
Allerdings wird der code schon nach unten hin weiter ausgeführt und findet dort dann kein sideani_link bzw nur einen leeren String.

Du müsstest dies hier noch in die if Abfrage in bei der XML reinpacken. Dann dürfte es funktionieren

mcLoader.addListener(listener);
mcLoader.loadClip(sideani_link, contentcontainer);

 

[dreamer2007]

Genau daran lags.... vielen Dank!

Gruß,

Dreamer