✔ Mausgeschwindigkeit ändern

[SpongeBernd]

Ich und meine Schwester teilen uns einen PC. Das Problem besteht nur darin, dass ich lieber eine schnelle Maus will und meine Schwester eine langsame. Ich dachte, dass man vielleivht mit VB ein kleines Prog schreiben könnte, mit dem man schnell und einfach die Geschwindigleit ändern kann ohne immer in der Systemsteuerung herumzumachen.

Kann mir da jemand weiterhelfen?

Danke schon mal im vorraus.

 

[wincnc]

Hallo, hier ein kleines Beispiel.
Du benötigst eine HScrollBar (HScroll1) und ein Label (Label1).

Private Declare Function SystemParametersInfo Lib "user32" Alias _
        "SystemParametersInfoA" (ByVal uAction As Long, ByVal uParam _
        As Long, ByRef lpvParam As Any, ByVal fuWinIni As Long) As _
        Long

Private Const SPI_GETMOUSESPEED = 112
Private Const SPI_SETMOUSESPEED = 113

Private Geladen As Boolean

Private Sub Form_Load()
Dim Result As Long
      
  HScroll1.Value = 1
  HScroll1.Min = 1
  HScroll1.Max = 20
  HScroll1.SmallChange = 1
  HScroll1.LargeChange = 2
  
  Label1.Alignment = 2
  
  Call SystemParametersInfo(SPI_GETMOUSESPEED, 0, Result, 0)
  HScroll1.Value = Result
  Label1.Caption = CStr(Result)
  
  Geladen = True
 
End Sub

Private Sub HScroll1_Change()
Dim V As Long
    
  If Geladen = False Then Exit Sub
    
  V = HScroll1.Value
  If V < 1 Then V = 1
  If V > 20 Then V = 20
        
  Call SystemParametersInfo(SPI_SETMOUSESPEED, 0&, ByVal V, 0&)
  Label1.Caption = HScroll1.Value

End Sub

Private Sub HScroll1_Scroll()
  HScroll1_Change
End Sub

 

[SpongeBernd]

Danke

Genau das, was ich gesucht hab ;-) ;-) ;-)

 

[broken-promise]

Hallo, gibt es denn auch eine Möglichkeit Buttons zu erstellen mit denen die Geschwindigkeit automatisch z.B: auf 10 gestellt wird?

 

[wincnc]

Hallo, ja die gibt es:

Private Declare Function SystemParametersInfo Lib "user32" Alias _
        "SystemParametersInfoA" (ByVal uAction As Long, ByVal uParam _
        As Long, ByRef lpvParam As Any, ByVal fuWinIni As Long) As _
        Long

Private Const SPI_SETMOUSESPEED = 113

Private Sub Command1_Click()
  Call SystemParametersInfo(SPI_SETMOUSESPEED, 0&, ByVal 10, 0&)
End Sub