Eintrag in einer DB Abfragen

[TaylorDorton]

Hallo,

ich möchte etwas in eine Datenbank schreiben,
vor dem schreiben aber Prüfen ob dieser Datensatz bereits aufgenommen ist.
Sollte das der Fall sein, erscheint eine Fehlermeldung.
Wenn nicht wird in die DB geschrieben. Mit dem Code
Den Ihr hier seht passiert aber folgendes, es gibt keine Fehlermeldung
Und der Eintrag wird munter immer wieder in die DB geschrieben.

Für Hilfe und Anregungen wäre ich sehr Dankbar.
Greetz Taylor

Sub TabelleSchreiben()
    Const TabName = "TVH VOen"
    Dim RS As DAO.Recordset
    Dim DB As DAO.Database
    Dim strVO As String
    
    strVO = "Test"

'Tabelle öffnen
    Set DB = Application.CurrentDb
    Set RS = DB.OpenRecordset("TVH VOen")

'Datensatz Übereinstimmung Abfragen
    If RS.Fields("VO") = True Then
        Select Case RS.Fields("VO").Value
            Case Is = strVO
            MsgBox "Vorhanden"
            Case Is = True
            RS.MoveNext
            Case Is = False
        End Select
    ElseIf RS.Fields("VO") = False Then
        RS.AddNew
        RS!VO.Value = strVO
        RS.Update
    End If
    
End Sub

 

[JensG]

Hallo,

versuche es mal so.

Sub TabelleSchreiben()
    Const TabName = "TVH VOen"
    Dim RS As DAO.Recordset
    Dim DB As DAO.Database
    Dim strVO As String
    
    strVO = "Test"

'Tabelle öffnen
    Set DB = Application.CurrentDb
    Set RS = DB.OpenRecordset("Select VO from `TVH VOen` where VO = '" & strVO & "'")


'Datensatz Übereinstimmung Abfragen
    If Not RS.EOF Then
        MsgBox "Vorhanden"
   
    Else
        RS.AddNew
        RS!VO.Value = strVO
        RS.Update
    End If    
End Sub

Jens