DirListBox

[BruS]

Hallo Zusammen!

Hab mal eine Frage und zwar das betrifft die DirListBox.

Soweit funktioniert ja alles, es wird mir der Verzeichnissbaum angezeigt denn ich haben will, wenn ich jetzt aber einen Ordner in dieser Box anklicke wird mir der Inhalt nicht angezeigt.

D.h Ich will z.B. einen Ordner öffnen wo sich ein Video drinnen befindet und dieses Video möchte ich anschließend mittels einem Doppelklick im MediaPlayer abspielen lassen.

Hab keinen Plan wie ich den Inhalt des Ordners in der DirListBox anzeigen lassen kann.

Hoffe Ihr könnt mir helfen

 

[wincnc]

Hallo

Dazu brauchst Du noch eine FileListBox (File1).

Private Sub Dir1_Change()
  Me.File1.Path = Dir1.Path
End Sub

 

[BruS]

Hallo!

Wow DANKE für die rasche Antwort!

Funktioniert Super!

Hab jetzt nur noch eine kleine Frage, wenn ich jetzt auf das Video einen Doppelklick mache wie funktioniert es das,das Video dann automatisch im Media Player abgespielt wird?

 

[wincnc]

Soll das Video extern im Player oder auf Deiner Form abgespielt werden?

 

[BruS]

Es sollte beides können!

Dh. wenn ich das file in der Forme anklicke soll als erstes eine kleine Art von Vorschau in einer PictureBox stattfinden.

Wenn ich dann zweimal draufklicke soll sich das Video im Windows Media player oder VLC Media Player ist dann egal gleich in Vollbild öffnen.

Hoffe du kannst mir da weiterhelfen.

Danke

 

[wincnc]

Mit einem Doppelklick kannst Du die Datei so öffnen:

Private Declare Function GetDesktopWindow Lib "user32" _
  () As Long
  
Private Declare Function GetSystemDirectory Lib "kernel32" _
  Alias "GetSystemDirectoryA" (ByVal lpBuffer As String, _
  ByVal nSize As Long) As Long

Private Const SE_ERR_NOASSOC = 31
Private Const SE_ERR_NOTFOUND = 2

Private Declare Function ShellExecute Lib "shell32.dll" _
  Alias "ShellExecuteA" (ByVal hWnd As Long, _
  ByVal lpOperation As String, ByVal lpFile As String, _
  ByVal lpParameters As String, _
  ByVal lpDirectory As String, _
  ByVal nShowCmd As Long) As Long

Private Sub File1_DblClick()
DocumentOpen File1.Path & "\" & File1.List(File1.ListIndex)
End Sub

Private Sub Form_Load()
File1.Pattern = "*.xls"
File1.Path = "D:\Eigene Dateien\Allgemein"
End Sub

Public Sub DocumentOpen(sFilename As String)
  Dim sDirectory As String
  Dim lRet As Long
  Dim DeskWin As Long
  
  DeskWin = GetDesktopWindow()
  lRet = ShellExecute(DeskWin, "open", sFilename, _
    vbNullString, vbNullString, vbNormalFocus)

  If lRet = SE_ERR_NOTFOUND Then
    
  ElseIf lRet = SE_ERR_NOASSOC Then
    sDirectory = Space(260)
    lRet = GetSystemDirectory(sDirectory, Len(sDirectory))
    sDirectory = Left(sDirectory, lRet)
    Call ShellExecute(DeskWin, vbNullString, _
      "RUNDLL32.EXE", "shell32.dll,OpenAs_RunDLL " & _
      sFilename, sDirectory, vbNormalFocus)
  End If
End Sub

Bei der Vorschau auf der Form muss ich passen.

 

[BruS]

Danke nochmal für deine Hilfe!

Hab das mit dem Media-Player auch noch gelöst.

Schönen Tag noch!