brauche Hilfe bei Bilder Zoom - Rollover

[gnom]

Moin wehrte Gemeinde,

ich komm nun garnicht mehr weiter und auf das alte Posting hat sich keiner mehr gemeldet. Hoffe einer kann mir nun weiter helfen.

Ich hab "Bilder" die bei einem mouseover zommen. alle rechts davon gehen weg, dass keines überdeckt wird, aber die links davon machen das nicht. Kann man das irgendwie anders gestalten. hab schon einiges ausprobiert, aber keinen Erfolg gehabt.



Beste

Ben

 

[Jens B.]

Hier:

var gap = clip2._x - (clip1._x - clip1._width); //Abstand zwischen Bildern = 92
var dest = 1;
var kleiner = false;
//Funktionen für mouserollover und mouserollout

for (var i=1; i<=4; i++) {
	this["clip" + i].onRollOver = function() {
		dest = parseInt(this._name.charAt(4)); 
		kleiner = false;
		_root.onEnterFrame = function() { scale_all() };
	}
	this["clip" + i].onRollOut = this["clip" + i].onDragOut = function() {
		dest = parseInt(this._name.charAt(4)); 
		kleiner = true;
		_root.onEnterFrame = function() { scale_all() };
	}
}

function scale_all() {
	var done = true;
	
	// Schritt 1: den MC skalieren
	if(!kleiner) {
		if(_root["clip" + dest]._width < 63) {
			done = false;
			_root["clip" + dest]._width +=  (63 - _root["clip" + dest]._width)  / 7;
			_root["clip" + dest]._height += (63 - _root["clip" + dest]._height) / 7;
		}
	}
	// ... oder kleiner machen
	for(var i = 1; i<=4; i++) {
		if(i != dest || kleiner) {
			if(_root["clip" + i]._width > 43) {
				done = false;
				_root["clip" + i]._width +=  (42 - _root["clip" + i]._width)  / 7;
				_root["clip" + i]._height += (42 - _root["clip" + i]._height) / 7;
			}
		}
	}
	
	// Schritt 2: alle MCs rechts davon nach rechts bewegen
	for(var i = dest + 1; i <= 4; i++) {
		_root["clip" + i]._x = _root["clip" + (i-1)]._x + (_root["clip" + (i-1)]._width / 2) + 8 + (_root["clip" + i]._width / 2);
	}
	
	// Schritt 3: alle MCs links davon nach links bewegen
	for(var i = dest - 1; i > 0; i--) {
		_root["clip" + i]._x = _root["clip" + (i+1)]._x - (_root["clip" + (i+1)]._width / 2) - 8 - (_root["clip" + i]._width / 2);
	}
	
	if(done) _root.onEnterFrame = null;
}

Generell solltest du langsam mal den Schritt zu AS3 wagen...

 

[gnom]

Vielen Danke Jens für die Antwort. Das mit AS3 hab ich mir schon einige male überlegt, jedoch hab ich mit AS2 noch meine Probleme und hab wirklich Angst auf AS3 umzusteigen. bis jetzt habe ich auch kein wirklich einleuchtendes und nicht abschreckendes Tutorial zu AS3 gefunden. Aber ich werde auf jedenfall dran bleiben, vielleicht find ich ja mal was.

Vielen Dank erst einmal und bis zum nächsten mal.

Beste

Ben

 

[Jens B.]

Bzgl des Tutorials schau mal unter folgendem Link (die Seite ist im Moment noch im Aufbau!)

http://jens-uwe-bahr.de/flashtutorials/