1. Diese Seite verwendet Cookies. Wenn du dich weiterhin auf dieser Seite aufhältst, akzeptierst du unseren Einsatz von Cookies. Weitere Informationen

Mail via Lotus Notes versenden

Dieses Thema im Forum "Visual Basic 6.0, VBA & VBScript" wurde erstellt von bullayer, 14. März 2007.

  1. bullayer

    bullayer Gast

    Hallo,
    ich suche eine Möglichkeit, via VB 6.0 und Lotus Notes eine Mail mit Anhang zu versenden. Hat jemand Beispielcodes, wie man sowas bewerkstelligen kann?
  2. Jacka

    Jacka Erfahrenes Mitglied

    Hi!

    Hier ist mein Code den ich verwende (Client muss geöffnet sein):
    Code (Text):
    1.  
    2.  
    3. Public Sub SendNotesMail()
    4.  
    5. Dim Subject As String, attachment As String, bodytext As String, saveit As Boolean
    6. Dim ToAdressen(10) as String
    7.  
    8. 'Achtung! Der Notes Client muss auf dem System installiert sein!
    9.  
    10.     Dim Maildb As Object 'Die Datenbank
    11.     Dim UserName As String 'Der Benutzername
    12.     Dim MailDbName As String 'Der Datenbankname
    13.     Dim MailDoc As Object 'Das Maildokument selbst
    14.     Dim AttachME As Object 'Der Anhang (Richtext)
    15.     Dim Session As Object 'Die Notes Session
    16.     Dim EmbedObj As Object 'Ein eingebettetes Objekt (Anhang)
    17.     Dim Recip(2) As Variant
    18.     Dim LinkME As Object
    19.     Dim testlink As String
    20.      
    21.     Subject = xpText4.Text
    22.     bodytext = xpText5.Text
    23.     attachment = AppPfad & "\Links.xls"
    24.            
    25.     'Die Session starten
    26.     Set Session = CreateObject("Notes.NotesSession")
    27.  
    28.  On Error GoTo Fehler:
    29.     'Den Benutzernamen auslesen und den Dateinamen
    30.     'der MailDB errechnen
    31.     'Dies wird nicht überall benötigt. Auf manchen
    32.     'Systemen kann auch ein leerer String übergeben werden
    33.     UserName = Session.UserName
    34.     MailDbName = Left$(UserName, 1) & Right$(UserName, (Len(UserName) - InStr(1, UserName, " "))) & ".nsf"
    35.    
    36.     'Datenbank öffnen
    37.     Set Maildb = Session.GetDatabase("", MailDbName)
    38.      If Maildb.IsOpen = True Then
    39.      Else
    40.          Maildb.OPENMAIL
    41.      End If
    42.      
    43.     'Ein neues Maildokument erstellen
    44.     Set MailDoc = Maildb.CreateDocument
    45.     MailDoc.Form = "Memo"
    46.     MailDoc.sendto = Recip
    47.     MailDoc.Subject = Subject
    48.     MailDoc.body = bodytext
    49.     MailDoc.SaveMessageOnSend = True
    50.        
    51.     'Eingebettete Objekte und Anhänge hinzufügen
    52.     If attachment <> "" Then
    53.         Set AttachME = MailDoc.CreateRichTextItem("Attachment")
    54.         Set EmbedObj = AttachME.EmbedObject(1454, "", attachment, "Attachment")
    55.         'MailDoc.CREATERICHTEXTITEM ("Attachment")
    56.     End If
    57.    
    58.     'Senden
    59.     MailDoc.PostedDate = Now()
    60.  
    61. If ToAdressen(1) = "" Then
    62.     MsgBox "Please enter recipients!"
    63.     GoTo Fehler2
    64. Else
    65.     MailDoc.Send 0, ToAdressen
    66.     MsgBox "Message transmitted"
    67.     GoTo Fehler2
    68. End If
    69.    
    70.     'Aufräumen
    71.     Set Maildb = Nothing
    72.     Set MailDoc = Nothing
    73.     Set AttachME = Nothing
    74.     Set Session = Nothing
    75.     Set EmbedObj = Nothing
    76.        
    77. Fehler:
    78.     MsgBox "Please open your Lotus Notes client!"
    79.     Exit Sub
    80.  
    81. Fehler2:
    82.     Exit Sub
    83.        
    84. End Sub
    85.  
    Oder unter den folgende Link schauen:
    http://www.activevb.de/tipps/vb6tipps/tipp0544.html

    Viele Grüße,
    Jacka
  3. bullayer

    bullayer Gast

    Danke @Jacka, funktioniert.

    Kennst Du auch ne Möglichkeit, ne Mail zu versenden, ohne dass ein Mailclient installiert ist, z. Bsp. via WEB.DE
    Zuletzt von einem Moderator bearbeitet: 15. März 2007
  4. Alex F.

    Alex F. Erfahrenes Mitglied

    es gibt die möglichkeit mails mittels ie (hierzu kann man die adressenleiste irgendwie misbrauchen) zu versenden oder auch mit der vbsendmail von activevb.

    Bei der Möglichkeit über den ie ist es wohl nicht möglich anhänge mit zu senden. Deswegen ist die VBsendmail eleganter
  5. Jacka

    Jacka Erfahrenes Mitglied

  6. bullayer

    bullayer Gast

    Danke an alle, funktioniert alles prächtig
  7. Rhinowsurfer

    Rhinowsurfer Grünschnabel

    Frage an Jacka:

    Hallo und guten Tag,
    bin unter den Laien einer der Größten. Ich kupfere immer nur ab, was andere irgendwie veröffentlicht haben, wenn ich es gebrauchen kann. Habe aber kaum Ahnung mit diesen ganzen Programmierbefehlen: Kurz um: Habe diesen Link aus einem Excel-Forum bekommen: Wir haben auf der Maloche Excel2003 und LotusNotes 6.5.5

    Habe naiv das Programm von Jacka in VBA Excel-Datei eingesetzt. Leider läuft es gar nicht. Muss ich irgendwo für Platzhalter, die im Programm vielleicht stehen, etwas anderes einsetzen'?

    Wenn ich das Makro starten will dann kommt gleich der Fehler:
    Fehler beim Kompilieren: Variable nicht definiert. Angezeigt wird dann z.B. text1 hinter dem Untermakro SendNotesMail.

    Ich hatte ja gehofft, dass den Code einfach bei mir einspiele und ich dann sofort in der Lage wäre, die entsprechende Excel-Seite als E-Mail versenden zu können.

    Kann da einem Unbedarften wie mir noch geholfen werden. Oder ist das für mich nicht darstellbar?

    Einen schönen Tag noch
    wünscht der
    Rhinowsurfer
  8. Rhinowsurfer

    Rhinowsurfer Grünschnabel

    Noch ein notwendiger Zusatz zu obiger Anfrage von mir
    Wir nutzen VBA 6.4.9972

    Gruß vom Rhinowsurfer
  9. Jacka

    Jacka Erfahrenes Mitglied

    Hi!

    Hab die Frage erst jetzt gesehen :D

    Also:

    Du benötigst für die Ausführung des Codes noch etwas:
    In Excel:
    Code (Text):
    1.  
    2.     .....  
    3.     Subject = Textbox1.Text   '  ist der Inhalt aus einer Textbox und ergibt den Betreff
    4.     bodytext = Textbox2.Text  '  ist der Inhalt aus einer weiteren Textbox und ergibt den  
    5.                                              email-Text
    6.     attachment = "C:\Liste.xls"  '  Die Excelliste die mit verschickt werden soll
    7.     .....
    8.     MailDoc.Send 0, ToAdressen  '  ToAdressen ist ein Array und enthält eben die  
    9.                                                   Empfänger-Adressen
    10.  
    Du kannst auch einfach Subject = "Dies ist der Betreff" schreiben
    Und:
    ToAdressen(0) = "abc@emailadresse.com"
    ToAdressen(1) = "xyz@emailadresse.com"

    Du hast sicher AppPfad nicht definiert. Ist bei mir eine public variable und
    definiert den Pfad, wo sich dann die EXE befinden.
    Das könnte deine Fehlermeldung erklären.

    Hoffe das hilft!
    Sonst schreib nochmal! :)

    Viele Grüße,
    Jacka
  10. Rhinowsurfer

    Rhinowsurfer Grünschnabel

    Hallo Jacka,

    habe Probleme!
    Habe Code, wie unten, eingegeben. Code läuft über Fehlerroutine aus.
    Das System erkennt Lotus nicht.
    Laienfrage von mir:
    Muss ich beim Start der Session
    Set session=createObject("Notes.NotesSession") :confused:
    in der Klammer 'was anderes eingeben?
    Beim schrittweisen Ablauf wird schon nichts in SESSION hineingeschrieben!

    Der UserName ist aber richtig gefüllt.(!)
    ----------
    ICh hatte mich ja als Laie und Abkupferer geoutet, also nicht böse sein, wenn die Frage auf unterem Niveau ist. ICh würde mich aber trotzdem freuen, wenn ich das mit Hilfe anderer hinbekommen würde. Denn nichts ist schöner, als hilfreiche Technik am Arbeitsplatz. Schönen Maifeiertag wünscht der Rhinowsurfer!



    Public Sub SendNotesMail()

    Dim Subject As String, attachment As String, bodytext As String, saveit As Boolean
    Dim ToAdressen(10) As String

    'Achtung! Der Notes Client muss auf dem System installiert sein!

    Dim Maildb As Object 'Die Datenbank
    Dim UserName As String 'Der Benutzername
    Dim MailDbName As String 'Der Datenbankname
    Dim MailDoc As Object 'Das Maildokument selbst
    Dim AttachME As Object 'Der Anhang (Richtext)
    Dim Session As Object 'Die Notes Session
    Dim EmbedObj As Object 'Ein eingebettetes Objekt (Anhang)
    Dim Recip(2) As Variant
    Dim LinkME As Object
    Dim testlink As String

    ' Subject = xpText4.Text
    ' bodytext = xpText5.Text
    ' attachment = AppPfad & "\Links.xls"
    Subject = "Dies ist der Betreff"
    bodytext = "E-Mail-Text"
    attachment = "U:\ABLAGE\BOC1\BOC15\4455\HV\WVS-Listen.xls"


    'Die Session starten
    Set Session = CreateObject("Notes.NotesSession")

    On Error GoTo Fehler:
    'Den Benutzernamen auslesen und den Dateinamen
    'der MailDB errechnen
    'Dies wird nicht überall benötigt. Auf manchen
    'Systemen kann auch ein leerer String übergeben werden
    UserName = Session.UserName
    MailDbName = Left$(UserName, 1) & Right$(UserName, (Len(UserName) - InStr(1, UserName, " "))) & ".nsf"

    'Datenbank öffnen
    Set Maildb = Session.GetDatabase("", MailDbName)
    If Maildb.IsOpen = True Then
    Else
    Maildb.OPENMAIL
    End If

    'Ein neues Maildokument erstellen
    Set MailDoc = Maildb.CreateDocument
    MailDoc.Form = "Memo"
    MailDoc.sendto = Recip
    MailDoc.Subject = Subject
    MailDoc.body = bodytext
    MailDoc.SaveMessageOnSend = True

    'Eingebettete Objekte und Anhänge hinzufügen
    If attachment <> "" Then
    Set AttachME = MailDoc.CreateRichTextItem("Attachment")
    Set EmbedObj = AttachME.EmbedObject(1454, "", attachment, "Attachment")
    'MailDoc.CREATERICHTEXTITEM ("Attachment")
    End If

    'Senden
    MailDoc.PostedDate = Now()

    If ToAdressen(1) = "" Then
    MsgBox "Please enter recipients!"
    GoTo Fehler2
    Else
    MailDoc.Send 0, ToAdressen
    MsgBox "Message transmitted"
    GoTo Fehler2
    End If

    'Aufräumen
    Set Maildb = Nothing
    Set MailDoc = Nothing
    Set AttachME = Nothing
    Set Session = Nothing
    Set EmbedObj = Nothing

    Fehler:
    MsgBox "Please open your Lotus Notes client!"
    Exit Sub

    Fehler2:
    Exit Sub

    End Sub
  11. Zvoni

    Zvoni Erfahrenes Mitglied

    Holladrio! Endlich mal ein gutes VB-Forum auf deutsch.
    Bin nicht umhin gekommen, dieses Thema zu lesen, da ich im Moment genau das in der Firma coden muss!

    Prinzipiell:
    Gut: Der allgemeine Code von Jacka
    Schlecht: In Mehrbenutzerumgebungen und zu starre Parametrisierung!!

    Ich werde mal meine Variante hier reinsetzen. Ihr werdet ein paar deutliche Unterschiede bemerken. Hinweis: Habe den ganzen Code in ein Klasse gesetzt, mit nur "SendNotesMail" als öffentlicher Methode, deshalb auch der "Initialize"-Code

    Code (Text):
    1.  
    2. Private Declare Function GetPrivateProfileString Lib "kernel32" _
    3.   Alias "GetPrivateProfileStringA" ( _
    4.   ByVal lpApplicationName As String, _
    5.   ByVal lpKeyName As Any, _
    6.   ByVal lpDefault As String, _
    7.   ByVal lpReturnedString As String, _
    8.   ByVal nSize As Long, _
    9.   ByVal lpFileName As String) As Long
    10.  
    11. Private Declare Function RegOpenKeyEx Lib "advapi32.dll" Alias "RegOpenKeyExA" (ByVal hKey As Long, ByVal lpSubKey As String, ByVal ulOptions As Long, ByVal samDesired As Long, phkResult As Long) As Long
    12. Private Declare Function RegQueryValueEx Lib "advapi32.dll" Alias "RegQueryValueExA" (ByVal hKey As Long, ByVal lpValueName As String, ByVal lpReserved As Long, lpType As Long, lpData As Any, lpcbData As Long) As Long
    13. Private Declare Function RegCloseKey Lib "advapi32.dll" (ByVal hKey As Long) As Long
    14.  
    15. Private Const HKEY_CURRENT_USER = &H80000001
    16. Private Const KEY_READ = &H20019
    17. Private Const REG_SZ = 1
    18.  
    19. Private Pfad As String
    20. Private MailFile As String
    21.  
    22. Private Function ReadReg() As String
    23. Dim RetVal As Long
    24. Dim hKey As Long
    25. Dim TmpSNum As String * 1280
    26.  
    27.   ' Registryschlüssel öffnen
    28.   RetVal = RegOpenKeyEx(HKEY_CURRENT_USER, "Software\Lotus\Notes\7.0", 0&, KEY_READ, hKey)
    29.  
    30.   If RetVal <> 0 Then
    31.    
    32.     RetVal = RegOpenKeyEx(HKEY_CURRENT_USER, "Software\Lotus\Notes\6.0", 0&, KEY_READ, hKey)
    33.    
    34.     If RetVal <> 0 Then
    35.    
    36.         MsgBox "Der Schlüssel konnte nicht geöffnet werden."
    37.         Exit Function
    38.        
    39.     End If
    40.    
    41.   End If
    42.  
    43.   ' Wert auslesen
    44.   RetVal = RegQueryValueEx(hKey, "NotesIniPath", 0, REG_SZ, _
    45.     ByVal TmpSNum, Len(TmpSNum))
    46.   If RetVal <> 0 Then
    47.     MsgBox "Der Schlüsselwert konnte nicht gelesen oder gefunden werden."
    48.    
    49.     Exit Function
    50.   End If
    51.    
    52.     ReadReg = Left$(TmpSNum, InStr(1, TmpSNum, vbNullChar) - 1)
    53.  
    54.   ' Schlüssel wieder schliessen
    55.   RetVal = RegCloseKey(hKey)
    56. End Function
    57.  
    58. Private Sub Class_Initialize()
    59. Dim TmpRetStr As String * 1280
    60. Dim RetVal As Long
    61.  
    62.     Pfad = ReadReg
    63.  
    64.     RetVal = GetPrivateProfileString("Notes", "MailFile", "Fehler", TmpRetStr, Len(TmpRetStr), Pfad)
    65.  
    66.     If RetVal > 0 Then MailFile = Left$(TmpRetStr, RetVal)
    67.  
    68. End Sub
    69.  
    70. Public Sub SendNotesMail(Subject As String, Attachment As String, BodyText As String, SaveIt As Boolean, ParamArray Recipient() As Variant)
    71. 'Variablen Dimensionieren, die benötigt werden, um das Mail zu senden
    72.     Dim Maildb As Object  'Die Datenbank
    73.     Dim UserName As String 'Der Benutzername
    74.     Dim MailDoc As Object  'Das Maildokument selbst
    75.     Dim AttachME As Object  'Der Anhang (Richtext)
    76.     Dim Session As Object 'Die Notes Session
    77.     Dim EmbedObj As Object  'Ein eingebettetes Objekt (Anhang)
    78.     Dim Adressen() as Variant
    79.    
    80.     Adressen=Recipient
    81.  
    82.     'Die Session starten
    83.     Set Session = CreateObject("Notes.NotesSession")
    84.        
    85.     'Datenbank öffnen
    86.     Set Maildb = Session.GETDATABASE("", MailFile)
    87.      If Maildb.IsOpen = True Then
    88.           'Fertig zum mailen!
    89.      Else
    90.          Maildb.OPENMAIL
    91.      End If
    92.      
    93.     'Ein neues Maildokument erstellen
    94.     Set MailDoc = Maildb.CREATEDOCUMENT
    95.     MailDoc.Form = "Memo"
    96.     MailDoc.sendto = Recipient(0)
    97.     MailDoc.Subject = Subject
    98.     MailDoc.body = BodyText
    99.     MailDoc.SAVEMESSAGEONSEND = SaveIt
    100.    
    101.     'Eingebettete Objekte und Anhänge hinzufügen
    102.     If Attachment <> "" Then
    103.         Set AttachME = MailDoc.CREATERICHTEXTITEM("Attachment")
    104.         Set EmbedObj = AttachME.EMBEDOBJECT(1454, "", Attachment, "Attachment")
    105.         'MailDoc.CREATERICHTEXTITEM ("Attachment")
    106.     End If
    107.    
    108.     'Senden
    109.     MailDoc.PostedDate = Now()
    110.     MailDoc.SEND 0, Adressen
    111.    
    112.     'Aufräumen
    113.     Set Maildb = Nothing
    114.     Set MailDoc = Nothing
    115.     Set AttachME = Nothing
    116.     Set Session = Nothing
    117.     Set EmbedObj = Nothing
    118. End Sub
    119.  
    Warum so umständlich? Ganz einfach: Lotus speichert in der Registry den Pfad zur Benutzerdefinierten INI-Datei, in welcher der korrekte Pfad zur NSF steht, und das ist eigentlich das, was ich brauche, deshalb: Erst in Registry gucken, wo die INI sitzt (ReadReg-Sub), dann hole den Pfad zur NSF aus der INI raus (RetVal = GetPrivateProfileString-Zeile in "Initialize"). (Fragt mich jetzt nicht, warum Lotus den Pfad zur NSF nicht in der Registry unter HKEY_CURRENT_USER speichert, weil da gehört das eigentlich hin!!)

    Die MailDBName-Berechnung mit
    Code (Text):
    1. MailDbName = Left$(UserName, 1) & Right$(UserName, (Len(UserName) - InStr(1, UserName, " "))) & ".nsf"
    ist NICHT gut!
    Was passiert, wenn ein Benutzer "Fritz Mueller" heisst, ein anderer "Frank Mueller"?
    In beiden Fällen käme mit der Formel "fmueller.nsf" heraus, was aber nicht eindeutig in einer Mehrbenutzer-Umgebung ist. Deshalb die Registry/INI-Klimmzüge


    ParamArray Recipient deshalb als Parameter-Array, weil ich immer min. 1 Empfänger brauche (-->Recipient(0)), Hierzu brauche ich aber vor Aufruf meiner Klassen-Methode SendNotesMail eine Plausibilitätsprüfung, dass Recipients mind. 1 Eintrag enthält. Wenn Recipients keinen Einträg enthält, wird die Klassen-Methode erst gar nicht aufgerufen. Wenn ich mehr habe, werden diese automatisch mitgegeben.
    Fragt mich jetzt aber nicht, warum ich
    Code (Text):
    1. Adressen=Recipient
    machen muss. Der Code weigert sich "MailDoc.SEND 0, Recipient" direkt auszuführen

    Desweiteren vermeide ich durch meine Variante dieses unsägliche "GoTo Fehler2"-Gedöns.

    Kommentare hierzu?
    Zuletzt bearbeitet: 4. Juli 2008
  12. DrSoong

    DrSoong Iss was, Doc! Premium-User

    Wenn du noch mehr solchen Code hast, stell den doch als Tutorial rein (auch den hier).


    Der Doc!
  13. mindsuk

    mindsuk Grünschnabel

    @Zvoni

    ich wollte gerade deine Variante testen, aber wenn ich in Excel Alt+F8 drücke, wird mir ihr nichts als Auswahl angezeigt? Da müsste doch SendNotesMail erscheinen...

    Hast Du einen Tipp?

    LG mindsuk


    P.S: Hintergrund ist auch, das ich das ganze als Makro einer Grafik zuordnen möchte!
    Zuletzt bearbeitet: 12. Januar 2012
  14. Zvoni

    Zvoni Erfahrenes Mitglied

    Das Zauberwort heisst KLASSE

    P.S.: Mittlerweile muss man den obigen Code sogar erweitern um
    Code (Visual Basic):
    1.  
    2.  RetVal = RegOpenKeyEx(HKEY_CURRENT_USER, "Software\Lotus\Notes\8.0", 0&, KEY_READ, hKey)
    ... da wir ja mittlerweile bei Lotus 8.5 sind.....
  15. Zvoni

    Zvoni Erfahrenes Mitglied

    Nachtrag: Die ReadReg-Funktion würde ich mittlerweile ein wenig anderst coden, und zwar mit dem Aufruf

    Code (Visual Basic):
    1.  
    2.  RetVal = RegOpenKeyEx(HKEY_CURRENT_USER, "Software\Lotus\Notes", 0&, KEY_READ, hKey)
    und sich dann weiter durch die Registry hangeln. Hab jetzt aber keinen Bock drauf *gg*
  16. mindsuk

    mindsuk Grünschnabel

    Guten Morgen und Danke für Deine Antwort. Ich muss dann noch einmal weiter ausholen.

    Ich habe ein Excel Sheet, welches ich zukünftig für meine Kunden als eine Art Bestellformular entworfen habe. Dort möchte ich zwei Buttons zum direkten versenden der Arbeitsmappe ohne Macros am Ende anbieten. Den ersten, zum versenden über Outlook habe ich erfolgreich erstellt und getestet. Nun versuche ich seit Tagen diesen für Lotus Notes zu basteln. Wenn ich in Excel Alt+F11 drücke, sehe ich das VBA Projekt und dort das Modul 1 mit dem Code für Outlook. Diesen konnte ich auch als Macho dem Button zuordnen.
    Wie und wo muss ich jetzt Deinen Code einfügen, damit ich das ganze dem Lotus Notes Butten zuordnen kann? Ein weiteres Modul anlegen und den Code dort einfügen?

    wäre super, wenn mir jemand helfen könnte..

    mindsuk
  17. Zvoni

    Zvoni Erfahrenes Mitglied

    Punkt 1: Die Excel-Mappe, in welcher dein Button und demzufolge das Makro ist, per Mail ohne Makros verschicken ist nicht******!

    An deiner Stelle, würde ich eher per Makro die ganzen relevanten Bestelldaten in ne Text-Datei schreiben, welche einem gewissen Satzaufbau folgt, und diese dann per E-Mail versenden.

    Auf der Empfängerseite brauchst du dann nur noch ein Makro, was die ganze Datei ausliest, und du hast die Bestellung in sauberer Form vorliegen.

    Punkt 2: Du musst im VB-Editor ein Klassenmodul (!!) einfügen, meinen Code komplett dort rein, dann schreibst du in deinem Modul 1 das Marko für den Lotus-Button, und aus diesem Makro heraus rufst du dann meine Klasse auf (Instanzierung nicht vergessen)
  18. mindsuk

    mindsuk Grünschnabel

    Hallo Zvoni, dazu kenne ich mich zu wenig mit der Materie aus!

    Notfalls kann die Mappe auch mit Macros gesendet werden, mich würde es nicht stören. Mir würde auch ein Textfile reichen, ein erneutes demodelieren müsste für meinen Geschmack gar nicht sein, Hauptsache ich kann die Positionen lesen.

    Ich habe kein Macro für den "Lotusbutto"n...das ist einfach ein GIF Symbol, welches ich verknüpfen möchte. Oder verstehe ich jetzt etwas falsch?

    LG
  19. Zvoni

    Zvoni Erfahrenes Mitglied

    Um ein Makro zu triggern brauchst du einen Auslöser, welchem man ein Makro zuordnen kann.
    Das sind meistens Steuerelemente, welche ein Click-Ereignis haben.

    Wenn du da nur so ein Bildchen hast, solltest du einfach mal prüfen, ob du diesem Bild ein Makro zuweisen kannst (Ich arbeite nunmal auch in Excel nur mit "echten" Steuerelementen)

    Falls ja, kann ich dir dann die Routine schreiben inkl. Klassenmodul etc.

    Oder ich mach dir ne Beispiel-Excel-Mappe mit allen Funktionen drin.
  20. mindsuk

    mindsuk Grünschnabel

    Hallo Zvoni, da es mit dem anderen Gif funktioniert hat, sollte es gehen. Wenn ich mit der rechten Maustaste auf das Gif gehe und auf Makro zuweisen, dann bekomme ich aber leider nur das Makro für die Mail über Outlook angeboten, welches ich bereits dem anderen Gif hinterlegt habe.

    Ich wäre Dir sehr dankbar, wenn Du mir da helfen könntest!!

    Liebe Grüße

Diese Seite empfehlen